I am trying to rollout 11.2 to all my clients.  I have over 400 clients in 11 locations.  I was pointed to unica after posting at the brianmadden forums.

I have found a script for the install of 11.2 at the citrix site that works good.  However the problem is that it will not install over the older clients.  I would like to incorporate unica to the citrix script. 

Can someone help with this?

Here is the scripts.

Setlocal

REM *********************************************************************

REM Customize the following variables

REM *********************************************************************

REM Set logshare to a central directory to collect log files

set logshare=\\Dc1\install\Citrix\Clients\11.2\logs\

set DesiredVersion=11.2.0

REM Set DeployDirectory to a location containing the Citrix online plug-in installer

set DeployDirectory=\\Dc1\install\Citrix\Clients\11.2

REM Set CommandlineOptions for the Citrix online plug-in installer

set CommandLineOptions=/silent ADDLOCAL="ICA_Client,SSON,Flash,USB" ENABLE_SSON="Yes"

echo %date% %time% the CheckAndDeployFULL.bat script is running >> %logshare%%ComputerName%.log

REM *********************************************************************

REM System verification

REM *********************************************************************

set CustomConfig=None

REM Check for any custom configuration files in the Default User profile

IF EXIST "%SYSTEMDRIVE%\Documents and Settings\Default User\Application Data\ICAClient" set CustomConfig=exists

IF EXIST "%SYSTEMDRIVE%\Users\Default\AppData\Roaming\ICAClient" set CustomConfig=exists

echo %date% %time% the CheckAndDeployFULL.bat script result for CustomConfig is %CustomConfig% >> %logshare%%ComputerName%.log

REM Check if the machine is 64bit

IF NOT "%ProgramFiles(x86)%"=="" SET WOW6432NODE=WOW6432NODE\

REM This script does not verify if a legacy client is already installed

REM Check if the desired online plug-in version is already installed

reg query "HKEY_LOCAL_MACHINE\SOFTWARE\%WOW6432NODE%Citrix\PluginPackages\XenAppSuite\ICA_Client" | findstr %DesiredVersion%

if %errorlevel%==1 (goto NotFound) else (goto Found)

REM If 1 is returned, the registry query found that the desired version is not installed

REM *********************************************************************

REM Deployment begins here

REM *********************************************************************

:NotFound

start /wait %DeployDirectory%\CitrixOnlinePluginFull.exe DONOTSTARTCC=1 %CommandLineOptions%

echo %date% %time% Setup ended with error code %errorlevel% >> %logshare%%ComputerName%.log

type %systemroot%\temp\TrolleyExpress*.log >> %logshare%%ComputerName%.log

if %CustomConfig%==exists goto End

REM Clean the Default User profile if custom configuration files did not exist

IF EXIST "%SYSTEMDRIVE%\Documents and Settings\Default User\Application Data\ICAClient" (

ECHO %date% %time% about to delete in XP-2003: >> %logshare%%ComputerName%.log

dir "%SYSTEMDRIVE%\Documents and Settings\Default User\Application Data\ICAClient" >> %logshare%%ComputerName%.log

RMDIR /S /Q "%SYSTEMDRIVE%\Documents and Settings\Default User\Application Data\ICAClient"

)

IF EXIST "%SYSTEMDRIVE%\Users\Default\AppData\Roaming\ICAClient" (

ECHO %date% %time% about to delete in Vista-WS08-Win7: >> %logshare%%ComputerName%.log

dir "%SYSTEMDRIVE%\Users\Default\AppData\Roaming\ICAClient" >> %logshare%%ComputerName%.log

RMDIR /S /Q "%SYSTEMDRIVE%\Users\Default\AppData\Roaming\ICAClient"

)

:Found

goto End

:End

Endlocal